dnl Process this file with autoconf to produce a configure script.
AC_INIT(src/reduce.c)
AM_INIT_AUTOMAKE(bison,1.28)
AM_CONFIG_HEADER(config.h:config.hin)
AC_PREREQ(2.13)

ALL_LINGUAS="de es fr nl"

dnl Checks for programs.
AC_PROG_CC
AC_MINIX
AC_ISC_POSIX
AM_PROG_CC_STDC
AC_PROG_INSTALL
AC_PROG_RANLIB

dnl Checks for libraries.

dnl Checks for header files.
AC_HEADER_STDC
AC_CHECK_HEADERS(ctype.h locale.h memory.h stdlib.h string.h unistd.h)

dnl Checks for typedefs.

dnl Checks for structures.

dnl Checks for compiler characteristics.
AC_C_CONST
AM_C_PROTOTYPES

dnl Checks for library functions.
AC_FUNC_ALLOCA
AC_CHECK_FUNCS(mkstemp setlocale)
BISON_NEED_DECLARATIONS(calloc realloc)

AM_GNU_GETTEXT

# This is necessary so that .o files in LIBOBJS are also built via
# the ANSI2KNR-filtering rules.
LIBOBJS=`echo $LIBOBJS|sed 's/\.o /\$U.o /g;s/\.o$/\$U.o/'`

AC_DEFINE_UNQUOTED(VERSION_STRING, "GNU Bison version ${VERSION}")
XPFILE="${datadir}/bison.simple"
BISON_DEFINE_FILE(XPFILE, XPFILE)
XPFILE1="${datadir}/bison.hairy"
BISON_DEFINE_FILE(XPFILE1, XPFILE1)
LOCALEDIR="${datadir}/locale"
BISON_DEFINE_FILE(LOCALEDIR, LOCALEDIR)

AC_OUTPUT(Makefile intl/Makefile po/Makefile.in src/Makefile doc/Makefile)
